DOIF/Zeitspanne zwischen zwei Terminen schalten
Eine aktuelle DOIF-Version ist erforderlich
Die hier gezeigten DOIF schalten eine Zeitspanne zwischen zwei Terminen.
Zeitspanne zwischen zwei Terminen mit DateTimePicker
Voraussetzung
Das erste DOIF nutzt das DateTimePicker-Widget. Dieses Widget muss vor der Nutzung des DOIF installiert werden.
Die Installation ist hier beschrieben: DateTimePicker: Download und Installation
Beschreibung
Hinweis: Verwendung von
- DateTimePicker
- readingList, setList, webCmd, cmdState
- $SELF für den Eigennamen des DOIF
- Defaultwert
- Ausgabeformatierung: [<Device>:<Reading>:"<Regex>":<Output>] zur Formatierung der Widgetdaten
- ["^global$:^MODIFIED $SELF$"] damit nach einem Modify DOIF in Status 2 schaltet
Das DOIF schaltet zwischen den angegebenen Terminen den Status auf 1, ausserhalb der Termispanne ist der Status 0.
Die Bedingung des DOIF wird täglich zur angegebenen Uhrzeit geprüft und es wird die vom Widget erzeugte Datumszeichenkette mit der Zeichenkette des aktuellen Datums verglichen. Wenn die Zeichenketten identisch sind wird der entsprechende Zweig geschaltet und ein Logeintrag erzeugt.
Durch die Ausgabeformatierung wird die Uhrzeit und das Datum extrahiert und in das passende Vergleichsformat gebracht. Das Widget liefert Tag und Monat mit zweistellig und ergänzt einstellige Angaben mit einer führenden Null. Der aktuelle Tag $mday und der Monat $month werden ohne führende Null geliefert, daher ist eine Formatanpassung notwendig
Readings
- [[$SELF:P_begin:"(\d\d:\d\d)$","00:00"]] gibt die Beginnzeit zurück, mit Vorgabe
- [[$SELF:P_ende:"(\d\d:\d\d)$","00:00"]] gibt die Endzeit zurück, mit Vorgabe
- "$year-$month-$mday" enthält das aktuelle Datum
- P_begin enthält die vom Widget gelieferte Zeichenkette für Startdatum und Startuhrzeit
- P_ende enthält die vom Widget gelieferte Zeichenkette für Enddatum und Enduhrzeit
Definition
([[$SELF:P_begin:"(\d\d:\d\d)$","00:00"]] and [?$SELF:P_begin:"^(\d\d).(\d\d).(\d\d\d\d)":($3*1)."-".($2*1)."-".($1*1)] eq "$year-$month-$mday")\
{Log 1, "Alarmstart"}\
DOELSEIF ([[$SELF:P_ende:"(\d\d:\d\d)$","00:00"]] and [?$SELF:P_ende:"^(\d\d).(\d\d).(\d\d\d\d)":($3*1)."-".($2*1)."-".($1*1)] eq "$year-$month-$mday" or ["^global$:^MODIFIED $SELF$"])\
{Log 1, "Alarmstop"}
wesentliche Attribute
cmdState 1|0 readingList P_begin P_ende setList P_begin:datetime,theme:"default",step:5,inline:true P_ende:datetime,theme:"default",step:5,inline:true webCmd P_begin:P_ende
Laborgruppe zum Import mit Raw definition
define datumsbereich_Labor1 DOIF ([[$SELF:P_begin:"(\d\d:\d\d)$","00:00"]] and [?$SELF:P_begin:"^(\d\d).(\d\d).(\d\d\d\d)":($3*1)."-".($2*1)."-".($1*1)] eq "$year-$month-$mday")\
{Log 1, "Alarmstart"}\
DOELSEIF ([[$SELF:P_ende:"(\d\d:\d\d)$","00:00"]] and [?$SELF:P_ende:"^(\d\d).(\d\d).(\d\d\d\d)":($3*1)."-".($2*1)."-".($1*1)] eq "$year-$month-$mday" or ["^global$:^MODIFIED $SELF$"])\
{Log 1, "Alarmstop"}
attr datumsbereich_Labor1 alias Terminspanne über Jahre,Monate und Tage
attr datumsbereich_Labor1 cmdState 1|0
attr datumsbereich_Labor1 group Labor: Datumsbereich von HH:MM dd.mm.yyyy bis HH:MM dd.mm.yyyy
attr datumsbereich_Labor1 icon time_calendar
attr datumsbereich_Labor1 readingList P_begin P_ende
attr datumsbereich_Labor1 room DOIF_Labor
attr datumsbereich_Labor1 setList P_begin:datetime,theme:"default",step:5,inline:true P_ende:datetime,theme:"default",step:5,inline:true
attr datumsbereich_Labor1 webCmd P_begin:P_ende
attr datumsbereich_Labor1 widgetOverride setList:textField-long
save
Zeitspanne zwischen zwei Terminen
Beschreibung
Hinweis: Verwendung von
- readingList, setList, webCmd, cmdState
- $SELF
- ["^global$:^MODIFIED $SELF$"] damit nach einem Modify DOIF in Status 2 schaltet
Das DOIF schaltet zwischen den angegebenen Terminen den Status auf 1, ausserhalb der Termispanne ist der Status 0.
Die Bedingung des DOIF wird täglich zur angegebenen Uhrzeit geprüft und es wird die vom Widget erzeugte Datumszeichenkette mit der Zeichenkette des aktuellen Datums verglichen. Wenn die Zeichenketten identisch sind wird der entsprechende Zweig geschaltet und ein Logeintrag erzeugt.
Es wird nicht geprüft, ob das angegebene Datum existiert. Es ist z.B. möglich, den 31.2.2017 einzustellen.
Readings
- [[$SELF:P_bhm,"00:00"]] enthält die Startzeit, mit Vorgabe
- [[$SELF:P_ehm,"00:00"]] enthält die Endzeit, mit Vorgabe
- "$year, $month, $mday" enthält das aktuelle Datum (Jahr, Monat, Tag)
- P_bday enthält den gewählten Starttag
- P_bmon enthält den gewählten Startmonat
- P_byear enthält das gewählte Startjahr
- P_eday enthält den gewählten Endtag
- P_emon enthält den gewählten Endmonat
- P_eyear enthält das gewählte Endjahr
Definition
([[$SELF:P_bhm,"00:00"]] and [?$SELF:P_byear] == $year and [?$SELF:P_bmon] == $month and [?$SELF:P_bday] == $mday)\
({Log 1, "Alarmstart"})\
DOELSEIF ([[$SELF:P_ehm,"00:00"]] and [?$SELF:P_eyear] == $year and [?$SELF:P_emon] == $month and [?$SELF:P_eday] == $mday)\
({Log 1, "Alarmstop"})
wesentliche Attribute
cmdState 1|0 readingList P_bhm P_bday P_bmon P_byear P_ehm P_eday P_emon P_eyear setList P_bhm:time P_bday:1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31 P_bmon:1,2,3,4,5,6,7,8,9,10,11,12 P_byear:2016,2017,2018,2019,2020,2021,2022,2023,2024,2025,2026 P_ehm:time P_eday:1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31 P_emon:1,2,3,4,5,6,7,8,9,10,11,12 P_eyear:2016,2017,2018,2019,2020,2021,2022,2023,2024,2025,2026
Laborgruppe zum Import mit Raw definition
define datumsbereich_Labor0 DOIF ([[$SELF:P_bhm,"00:00"]] and [?$SELF:P_byear] == $year and [?$SELF:P_bmon] == $month and [?$SELF:P_bday] == $mday)\
({Log 1, "Alarmstart"})\
DOELSEIF ([[$SELF:P_ehm,"00:00"]] and [?$SELF:P_eyear] == $year and [?$SELF:P_emon] == $month and [?$SELF:P_eday] == $mday)\
({Log 1, "Alarmstop"})
attr datumsbereich_Labor0 alias Terminspanne
attr datumsbereich_Labor0 cmdState 1|0
attr datumsbereich_Labor0 group Labor: Datumsbereich von HH:MM dd.mm.yyyy bis HH:MM dd.mm.yyyy ohne datetimepicker Widget
attr datumsbereich_Labor0 icon time_calendar
attr datumsbereich_Labor0 readingList P_bhm P_bday P_bmon P_byear P_ehm P_eday P_emon P_eyear
attr datumsbereich_Labor0 room DOIF_Labor
attr datumsbereich_Labor0 setList P_bhm:time\
P_bday:1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31 \
P_bmon:1,2,3,4,5,6,7,8,9,10,11,12\
P_byear:2016,2017,2018,2019,2020,2021,2022,2023,2024,2025,2026 P_ehm:time \
P_eday:1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31 \
P_emon:1,2,3,4,5,6,7,8,9,10,11,12 P_eyear:2016,2017,2018,2019,2020,2021,2022,2023,2024,2025,2026
attr datumsbereich_Labor0 webCmd P_bhm:P_bday:P_bmon:P_byear:P_ehm:P_eday:P_emon:P_eyear
attr datumsbereich_Labor0 widgetOverride setList:textField-long
save