Bewässerungssteuerung

Diese Seite beschreibt, wie man intelligent seine Bewässerung steuern kann wenn man zb. Bodenfeuchtesensoren installiert hat.

Es wird von folgenden Komponenten ausgegangen:

• Gardena Magnetventile, angesprochen über einen FS20-Aktor (zb. S8M)
• Bodenfeuchtesensoren, zb. FS20 BF oder andere (zb. an einem AVR-NET-IO)

allgemeine Einstellungen

Anlegen zusätzlicher Attribute

Es müssen folgende neue globale Attribute angelegt werden:

• schwellwert
• sensor

Anlegen der Bodenfeuchtesensoren

Für einen FS20 Sensor: FS20BF

define Bodenfeuchtesensor FS20 34f2 00
attr Bodenfeuchtesensor room Bewässerung

Für eine 1wire Version: einen analogen Sensor (zb. Vegetronix), angeschlossen an einen 4fach A/D Converter DS2450

define Bodenfeuchte OWAD DS2450 50310C000000 60
attr Bodenfeuchte AFunction VA*33.9
attr Bodenfeuchte AUnit percent|%
attr Bodenfeuchte BFunction VB*33.9
attr Bodenfeuchte BUnit percent|%
attr Bodenfeuchte CFunction VC*33.9
attr Bodenfeuchte CUnit percent|%
attr Bodenfeuchte event-on-change-reading state
attr Bodenfeuchte model DS2450
attr Bodenfeuchte room Bewässerung

Alternativ auch andere, siehe AVR-NET-IO

zentrale Schaltvariable

Erstellung einer Schaltvariable um im Frontend die Bewässerung zentral zu steuern

• Auto => Je nach Angabe des Bodenfeuchtesensors wird bewässert oder nicht
• On => Es wird immer bewässert
• Off => Es wird nicht bewässert

define Bewaesserung_Active dummy
attr Bewaesserung_Active room Bewässerung
attr Bewaesserung_Active setList Auto On Off
attr Bewaesserung_Active webCmd Auto:On:Off

Steuerung mittels 1wire

wird die Bewässerungssteuerung mittels 1Wire betrieben, so verfügt 1 Device (i.d.R DS2406/DS2408/DS1413) über 2 oder 8 Ports. Wie diese einerseits komfortabel per FHEM-Weboberfläche zu steuern als auch eine automatisierte Steuerung zu realisieren ist soll dieser Abschnitt aufzeigen.

Anlegen des Schalt-Devices

An folgendem Device hängen die physischen Bewässerungsventile. Dieses muss natürlich an die eigenen Gegebenheiten angepasst werden :)

define Schalter_links OWSWITCH DS2408 F4D210000000
attr Schalter_links event-on-change-reading A,B,C,D,E,F,G,H
attr Schalter_links model DS2408
attr Schalter_links room OWX

Anlegen der DummyDevices

Über diese "Schalter" werden die einzelnen Bewässerungsstränge gesteuert.

define Bewaesserung_Tomaten dummy
attr Bewaesserung_Tomaten alias Bewässerung Tomaten
attr Bewaesserung_Tomaten eventMap /on-for-timer 30:Anschalten/off:Ausschalten/
attr Bewaesserung_Tomaten group Bewässerung
attr Bewaesserung_Tomaten room OWX
attr Bewaesserung_Tomaten schwellwert 58
attr Bewaesserung_Tomaten sensor Schalter_links:A Bodenfeuchte:A
attr Bewaesserung_Tomaten webCmd Anschalten:Ausschalten

Auf der Weboberfläche erscheinen die Schalter "Anschalten" und Ausschalten". Diese werden mittels eventmap auf "on-for-timer 30" und "off" intern umgesetzt und später an den 1wireBaustein weitergegeben. Über das Attribut "sensor" wird eine Zuordnung zum tatsächlichen 1wireDevice als auch zum dazugehörigen Sensor vorgenommen und wird folgendermaßen definiert:

attr Bewaesserung_Tomaten sensor Device[:Port] [Bodenfeuchtesensor[:Port]]

Im Beispiel ist das 1wireDevice ein DS2408 und heißt "Schalter_links" und die Bewässerung der Tomaten hängt am Port A. Der zugehörige Bodenfeuchtesensor in den Tomaten hängt an einem DS2450 mit dem Namen "Bodenfeuchte" ebenfalls am Port A. Über den Schwellwert wird eingestellt, ab welcher Bodenfeuchte tatsächlich bewässert werden soll.

Anlegen des Notify´s für die DummySchalter

Folgendes Notify reagiert auf die Events der Dummyschalter. Es wird hier im Beispiel das Event "Anschalten" auf "on-for-timer 30" umgesetzt sowie das Sensor- und schwellwertattribut abgerufen. Das Sensorattribut wird in den Device- und Sensorabschnitt zergliedert. Anschließend wird mit den so ermittelten Parametern die zentrale Bewässerungsprozedur aufgerufen.

define Bewaesserung_Macro notify Bewaesserung.* {\
  my $device=$NAME;;\
  my @a = (undef, $EVENT);;\
  @a = ReplaceEventMap($device, \@a, 0);;\
  shift @a;;\
  my $status = join(" ", @a);;\
  my @temp = split(" ", AttrVal($device, "sensor", " "));;\
  my $schwellwert = AttrVal($device, "schwellwert", "");;\
\
  Log 5, "Prozeduraufruf: Bewaesserung($temp[0],$temp[1],$schwellwert,$status)";;\
  Bewaesserung($temp[0],$temp[1],$schwellwert,$status, $device);;\
}
attr Bewaesserung_Macro group Bewässerung
attr Bewaesserung_Macro room OWX 

zentrale Bewässerungsprozedur

Die zentrale Prozedur wird als UTIL Datei im FHEM Verzeichnis gespeichert. Hier wird die Entscheidung getroffen, ob bewässert werden soll oder nicht. Es wird die aktuelle Bodenfeuchte im Zusammenhang mit dem Schwellwert ausgewertet sowie die globale Einstellung "Auto"/"On"/"Off"

##############################################
# $Id:$
package main;

use strict;
use warnings;
use POSIX;
use URI::Escape;

sub
Utils_Bewaesserung_Initialize($$)
{
  my ($hash) = @_;
}

##############################################
# Prozedur zur Bewässerungssteuerung
# Parameter: 
#   1. Device:Port   (zb. Schalter:A)
#   2. Sensor:Port   (zb. MySens:C)
#   3. Schwellwert   (0-100 in % - zb. 55)
#   4. Timer Befehl  (zb. on-for-timer 30)
#   5. Dummy-Schalter (optional)
#
# Bsp: Bewaesserung("Schalter_links:A","Bodenfeuchte:A",56,"on-for-timer 30")
##############################################
sub
Bewaesserung($$$$$) {
  my ($device,$sensor,$schwellwert,$command,$dummyschalter) = @_;
  my ($deviceport, $sensorport); 
  my $auto = ReadingsVal("Bewaesserung_Active", "state", "Off");
  my $bodenfeuchte;
  my (@tempd, @temps);

  #es muss immer ein Command übergeben werden
  if($command !~ m/(on|on-for-timer|off)/) {
    Log 3, "Abbruch: Fehlende Angabe des Commands";
    return;
  }

  # falsche Schwellwertangabe
  if(defined($schwellwert) && $schwellwert !~ m/^(\d+)$/) {
    Log 3, "Schwellwert definiert, aber nicht nummerisch: $schwellwert";
    return;
  } 

  @tempd = split(":", $device)   if($device =~ m/:/);
  $device = $tempd[0];
  $deviceport = $tempd[1] if($tempd[1]);

  @temps = split(":", $sensor)   if($sensor =~ m/:/);
  $sensor = $temps[0];
  $sensorport = $temps[1] if($temps[1]);

  if(!$defs{$device}) {
    Log 3, "Fehlerhafte Angabe des Devices: $device";
    return;
  }

  if(defined($sensor) && !$defs{$sensor}) {
    Log 3, "Fehlerhafte Angabe des Sensors: $sensor";
    return;
  }

  
  if (($auto eq "Auto") && (!defined($sensor))) {
    Log 3, "Automatikmodus angefordert aber kein Sensor definiert.";
    return;
  } elsif (($auto eq "Auto") && (!defined($schwellwert))) {
    Log 3, "Automatikmodus angefordert aber kein Schwellwert definiert.";  
    return;
  } elsif(($auto eq "Auto") && (defined($sensor))) {
    # Status des Sensors abfragen  
    if (defined($sensorport)) { 
      $bodenfeuchte = ReadingsVal($sensor, $sensorport, undef) if (!defined($bodenfeuchte)); 
    } else {
      $bodenfeuchte = ReadingsVal($sensor, "state", undef)  if (!defined($bodenfeuchte));
      $bodenfeuchte = ReadingsVal($sensor, "status", undef) if (!defined($bodenfeuchte));
    }
    # im Fehlerfall setze Bodenfeuchte auf 100%
    if(!defined($bodenfeuchte)) {
      Log 3, "Kann Bodenfeuchte nicht ermitteln. Breche Vorgang ab.";
      $bodenfeuchte = 999;
    } else {
      #Bodenfeuchte ist kein Messwert sondern nur ein on/off Reading
      $bodenfeuchte = 0 if(lc($bodenfeuchte) =~ m/^(on)/);
      $bodenfeuchte = 101 if(lc($bodenfeuchte) =~ m/^(off)/);
    }
  } else {
    # kein sensor definiert und kein Automatikmodus, setze Bodenfeuchte auf 0% und
    # Schwellwert auf 100% damit bewässert wird
    $bodenfeuchte = 0;
    $schwellwert  = 100;
  }
  
  if(($auto eq "Auto") || ($auto eq "On")) {
    Log 3, "Modus: $auto -> Device: $device:$deviceport, Bodenfeuchte: $bodenfeuchte%, Schwellwert: $schwellwert%, DummySchalter: $dummyschalter";
    if ($schwellwert >= $bodenfeuchte) {
      Log 3, "fhem: set $device output $deviceport $command";
      fhem "set $device output $deviceport $command";
      if (defined($dummyschalter)) {
        Log 3, "fhem: setState $dummyschalter $command";
        Log 3, "fhem: on_for_timer_offcheck($dummyschalter, $command)";
        fhem "setState $dummyschalter $command";
        on_for_timer_offcheck($dummyschalter, $command);
      }
    } else {
      Log 3, "fhem: set $device output $deviceport off";
      fhem "set $device output $deviceport off";
      if (defined($dummyschalter)) {
        Log 3, "fhem: setState $dummyschalter off";
        fhem "setState $dummyschalter off";
      }
    }
  } #elsif Device ne off -> set Device off 
}

1;

Steuerung mittels FS20/einzelner Devices

Falls für jedes Magnetventil ein eigenes Device existiert. Zb. bei Nutzung von eines SM8/SM4/FS20ST

Bewässerungsventile definieren

Als erstes werden die Bewässerungsventile in FHEM definiert, zb.:

define Bewaesserung_Ventil1 FS20 2305 51
attr Bewaesserung_Ventil1 model fs20st
attr Bewaesserung_Ventil1 room Bewässerung

Zuweisung eines Sensors einem oder mehrerer Bewässerungsventile

Hier der Fall eines FS20BF Bodenfeuchtesensors. Dieser übermittelt nur im state ein "on" oder "off"

attr Bewaesserung_Ventil1 sensor Bodenfeuchtesensor

Im Falle der 1wire Version wird das Ventil 1 mit dem Bodenfeuchtesensor "gepaired" der am Port A des Sensors "Bodenfeuchte" hängt. Dieser übermittelt einen echten Dezimalwert.

attr Bewaesserung_Ventil1 sensor Bodenfeuchte:A

zentrale Prozedur zur Bewässerung

Jetzt wird die zentrale Prozedur zur Steuerung angelegt:

define BewNotify notify BewNotify {
 my @@args    = split(" ",'%EVENT');
 my $device   = "%EVTPART0";
 my $duration = "%EVTPART1";
 my $sensor   = AttrVal($device, "sensor", undef);
 my @@sArr    = split(":", $sensor)               if($sensor =~ m/:/);
 my $auto     = ReadingsVal("Bewaesserung_Active", "state", "Off");
 my $sensorstate = "on";
 my $schwellwert = 0;

 if(($auto eq "Auto") || ($auto eq "On")) {
   if((defined ($sensor)) && ($auto eq "Auto")) {
     if (defined($sArr[0])) { 
       $sensorstate = ReadingsVal($sArr[0], $sArr[1], undef); 
       $schwellwert = AttrVal($sArr[0], "schwellwert", undef);
       $schwellwert = AttrVal($sArr[0], $sArr[1]."Low", 0) if (!defined($schwellwert));
     } else {
       $schwellwert = AttrVal($sensor, "schwellwert", undef);
       $sensorstate = ReadingsVal($sensor, "state", undef)  if (!defined($sensorstate));
       $sensorstate = ReadingsVal($sensor, "status", undef) if (!defined($sensorstate));
     }
     $sensorstate = "off" if (!defined($sensorstate));
   } 
  
   if($sensorstate eq "on") {
      fhem "set $device on-for-timer $duration";
   } elsif ($sensorstate =~ m/^(\d+)/) {
     Log 5, "Sensorstate: $sensorstate";
     
     Log 5, "Schwellwert: $schwellwert";
     if ($schwellwert >= $sensorstate) { fhem "set $device on-for-timer $duration"; }
   } elsif (ReadingsVal($device, "state", "") ne "off" ) {
      fhem "set $device off";
   }
 }
}
attr BewNotify comment Prozedur um aufgrund Umweltzustände die Bewässerung freizugeben oder nicht. Bsp: BewNotify {Device} {Dauer in sek} {Schaltvariable}
attr BewNotify room Bewässerung

Das geübte Auge wird feststellen, das für die Bodenfeuchtesensoren sowohl das Reading "state" als auch das Reading "status" abgefragt wird. Das liegt daran, das die FS20 BF ein Reading "state" haben, die analogen Bodenfeuchtesensoren über die ECMDDevice classdef-Definition ein "status" Reading (Das Reading "state" ist intern verwendet und darf nicht doppelt vergeben werden).

Zeitsteuerung

6. Abschließend wird die Bewässerung in die Zeitsteuerung übergeben

define Timer_Ventil1 at *00:00:00 trigger BewNotify Bewaesserung_Ventil1 1920
attr Timer_Ventil1 room Bewässerung

Hiermit wird täglich um 0Uhr die Bewässerungsprozedur aufgerufen bei dem Ventil1 für 30min geöffnet wird. Abhängig natürlich von der Einstellung [Auto|On|Off] der Schaltariable "Bewaesserung_Active"